MacFormat 1997 February/macformat-047.iso/Demos/Picasso Interactive Demo/Data/Sequence/Sequence.Dxr/Internal_8_Sc. Debug.ls

Text File | 1996-12-02 | 4.4 KB | 107 lines

on ouvrirFenetreDebug
  global windowDebug, gPathDelimitor
  if objectp(windowDebug) then
    forget(windowDebug)
  end if
  set windowDebugRect to rect(1, 39, 321, 239)
  set windowDebug to window "Debug"
  set the rect of windowDebug to windowDebugRect
  set the fileName of windowDebug to the pathName & "Debug" & gPathDelimitor & "DEBUG.DIR"
  set the windowType of windowDebug to 4
  open(windowDebug)
  initialiserDebug()
  updaterDebug()
end

on initialiserDebug
  global windowDebug, g_call_param, gRefSequence, gNbEtapesSequence, gNumEtapeSequence, gListePausesNavigation, gListeIndex, gTypeTempoEtape, gElementSonEtape, gListeRefsIndexEtape, gListeTransitionEtape, gNumEtapeMax, gListeTransitions, gListeDeroulementSequence, gValeurTempoEtape
  set char1 to char 1 of gRefSequence
  set char2 to char 2 of gRefSequence
  set char3 to char 3 of gRefSequence
  set texteTitre to getNomSeq(char1, value(char2), value(char3))
  set texteListeIndex to EMPTY
  repeat with i = 1 to count(gListeIndex)
    set refIndex to getPropAt(gListeIndex, i)
    put refIndex && "->" && getAt(getaProp(gListeIndex, refIndex), 2) & RETURN after texteListeIndex
  end repeat
  delete line the number of lines in texteListeIndex of texteListeIndex
  tell windowDebug
    put gRefSequence into field "Ch. Sequence"
    put texteTitre into field "Ch. Titre"
    set texteSonsSequence to EMPTY
    set texteReperesSequence to EMPTY
    repeat with i = 1 to gNbEtapesSequence
      set listeEtape to getAt(gListeDeroulementSequence, i)
      set elementSonEtape to getAt(listeEtape, 4)
      if not (texteSonsSequence contains elementSonEtape) then
        put elementSonEtape & RETURN after texteSonsSequence
      end if
      set repereImpression to getAt(listeEtape, 6)
      if repereImpression = 1 then
        put i & "-" after texteReperesSequence
      end if
    end repeat
    delete char the number of chars in texteReperesSequence of texteReperesSequence
    delete line the number of lines in texteSonsSequence of texteSonsSequence
    set textePausesNav to EMPTY
    repeat with i = 1 to count(gListePausesNavigation)
      put getAt(gListePausesNavigation, i) & "-" after textePausesNav
    end repeat
    delete char the number of chars in textePausesNav of textePausesNav
    if voidp(g_call_param) then
      set texteG_Call_Param to "<Vide>"
    else
      set texteG_Call_Param to g_call_param
    end if
    put texteG_Call_Param into field "Ch. g_Call_Param"
    put textePausesNav into field "Ch. Navigation"
    put texteListeIndex into field "Ch. ListeIndex"
    put texteReperesSequence into field "Ch. Reperes"
    put texteSonsSequence into field "Ch. ListeSons"
  end tell
end

on updaterDebug
  global windowDebug, g_call_param, gRefSequence, gNbEtapesSequence, gNumEtapeSequence, gListePausesNavigation, gListeIndex, gTypeTempoEtape, gElementSonEtape, gListeRefsIndexEtape, gListeTransitionEtape, gNumEtapeMax, gListeTransitions, gListeDeroulementSequence, gValeurTempoEtape
  if gListeRefsIndexEtape = [] then
    set texteRefsIndexEtape to "Aucun"
  else
    set texteRefsIndexEtape to EMPTY
    repeat with i = 1 to count(gListeRefsIndexEtape)
      set refIndexEtape to getAt(gListeRefsIndexEtape, i)
      put refIndexEtape & "," after texteRefsIndexEtape
    end repeat
    delete char the number of chars in texteRefsIndexEtape of texteRefsIndexEtape
  end if
  if gListeTransitionEtape = [] then
    set texteTransitionEtape to "---"
  else
    set texteTransitionEtape to gListeTransitionEtape
  end if
  if gTypeTempoEtape = "NoDelay" then
    set texteTempoEtape to gTypeTempoEtape && "(-)"
  else
    set texteTempoEtape to gTypeTempoEtape && "(" & gValeurTempoEtape & ")"
  end if
  set texteEtape to 33
  if gNumEtapeSequence > 9 then
    set texteEtape1 to gNumEtapeSequence
  else
    set texteEtape1 to " " & gNumEtapeSequence
  end if
  if gElementSonEtape = EMPTY then
    set texteSonEtape to "Aucun"
  else
    set texteSonEtape to gElementSonEtape
  end if
  tell windowDebug
    put texteEtape1 into char 1 to 2 of field "Ch. Etape"
    put gNbEtapesSequence && "(" & gNumEtapeMax & ")" into char 4 to 10 of field "Ch. Etape"
    put texteTempoEtape into field "Ch. Tempo"
    put texteSonEtape into field "Ch. SonEtape"
    put texteRefsIndexEtape into field "Ch. Index"
    put getaProp(gListeTransitions, getAt(gListeTransitionEtape, 1)) into field "Ch. Transition"
    put texteTransitionEtape into field "Ch. CodeTransition"
  end tell
end